【Word】ワードを一括でpdf変換（複数：まとめて：ＶBAマクロ：違いも）する方法

いつも記事を読んでいただきありがとうございます！！！これからもお役に立てる各情報を発信していきますので、今後ともよろしくお願いします(^^)/

文書やアンケートなどさまざまな文書が作成できるワード（Word）。

ワードの機能を使いこなすことで、業務の効率化が図れます。

例えば、複数のワードファイルをpdfに一括変換したいと思ったことはありませんか？

今回は、ワードのファイルをpdfに変換する方法について解説していきます。

ワードファイルをpdfに変換する方法と各々の違い【基本】

ワードファイルをPDFに変換するにはいくつかの方法があります。

ワードファイルを開いた状態で、リボンから「ファイル」タブ→「エクスポート」→「PDF/XPSドキュメントの作成」→「PDF/XPSの作成」を選択し、「ファイルの種類」が「PDF」になっていることを確認して「発行」をクリックしてください。

もっと簡単に変換するのであれば、「F12」キーを押してエクスプローラーを起動し、「ファイルの種類」を「PDF」にしてから「保存」をクリックしてください。

こちらのほうが操作手順は少ないですが、慣れるまでは「エクスポート」の機能を使った方がミスがなくてよいでしょう。

ワードでpdfにまとめて・一括変換する方法

フリーソフトウェアを使うことで、複数のワードファイルを一括変換することができます。

以下などがwordからpdfに一括変換できるサイトの代表例ですね
※外部サイトに移行します※

I love pdfさんのサイト

変換したいファイルを選択し、ドラッグ＆ドロップで簡単に一括変換できます。

フリーソフトウェアを使うと、ファイルサイズの圧縮も行うことが出来ます。

大きすぎるPDFファイルはメールなどでうまく送信できないことがあります。スムーズに送信するためにも、上記サイトなどで圧縮するようにしましょう。

ワードファイルをpdfに一括変換する方法【マクロ(VBA)でまとめて】

マクロ（VBA）を活用してファイルを結合する方法もあります。

[Alt]＋[F11]キーでVBE画面を開き、次のコードを貼り付けてください。

Sub フォルダ内のWordファイルをPDFにして別のフォルダに保存()
    Dim fld As FileDialog 'フォルダ選択のダイアログ表示用
    Dim myFileName As String 'Wordファイル名
    Dim myFolderPath As String 'Wordファイル保存先のフォルダパス
    Dim myFilePath As String 'Wordファイル／PDFファイルのパス
    Dim myDoc As Document 'Wordファイルのオブジェクト
    Dim intPos As Integer 'Wordファイル名取得用のピリオドの位置
    Dim pdfFolderPath As String 'PDFファイル保存先のフォルダパス

    'フォルダの選択（Wordファイルが置かれているフォルダ）
    Set fld = Application.FileDialog(msoFileDialogFolderPicker)
    If fld.Show = 0 Then Exit Sub
    myFolderPath = fld.SelectedItems(1)
    myFileName = Dir(myFolderPath & "\*.doc*")
    If myFileName = "" Then
        MsgBox "選択したフォルダ内に、Wordファイルがありません。"
        Exit Sub
    End If

    '別のフォルダの選択（PDFファイル保存先のフォルダ）
    Set fld = Application.FileDialog(msoFileDialogFolderPicker)
    If fld.Show = 0 Then Exit Sub
    pdfFolderPath = fld.SelectedItems(1)

    'WordファイルをPDFファイルに変換して別のフォルダに保存
    Do While myFileName <> ""
        'Wordファイルを開く（非表示）
        myFilePath = myFolderPath & "\" & myFileName
        Set myDoc = Documents.Open(FileName:=myFilePath, Visible:=False)
        DoEvents

        '拡張子のない名称を取得
        intPos = InStrRev(myFileName, ".")
        myFileName = Left(myFileName, intPos - 1)

        'PDF形式で保存（ファイル名先頭に「PDF_」と挿入）
        myDoc.ExportAsFixedFormat _
            OutputFileName:=pdfFolderPath & "\PDF_" & myFileName & ".pdf", _
            ExportFormat:=wdExportFormatPDF
        DoEvents

        'Wordファイルを閉じる
        myDoc.Close wdDoNotSaveChanges
        DoEvents

        '次のWordファイルを検索
        myFileName = Dir()
    Loop

    Set myDoc = Nothing
    Set fld = Nothing
End Sub