【Excel】VBAマクロでフォルダ内のファイル名を取得（サブフォルダ内も：一覧に：すべて取得しセルに追記・入力）する方法【Dir関数、FileSystemObject】

Sub Get_File_Names()
    'フォルダパスを指定
    Dim folderPath As String
    folderPath = "C:\Sample"
    
    'ファイル名を保存する変数
    Dim fileName As String
    
    '行番号カウンター
    Dim rowCounter As Long
    rowCounter = 2
    
    'Dir関数でフォルダ内のファイル名を1つずつ取得
    fileName = Dir(folderPath & "\*.xlsx")
    
    'ファイル名が取得できる間繰り返し
    Do While fileName <> ""
        'シート1のB列、rowCounter行目にファイル名を入力
        Sheets(1).Range("B" & rowCounter).Value = fileName
        
        '次の行へ
        rowCounter = rowCounter + 1
        
        '次のファイル名を取得
        fileName = Dir()
    Loop
End Sub

Sub Get_File_Names_Recursive()
    'フォルダパスを指定
    Dim folderPath As String
    folderPath = "C:\Sample"
    
    '行番号カウンター
    Dim rowCounter As Long
    rowCounter = 2
    
    'FileSystemObjectを生成
    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")
    
    'フォルダを取得
    Dim targetFolder As Object
    Set targetFolder = fso.GetFolder(folderPath)
    
    '再帰的にファイル名を取得する関数を呼び出し
    ListFiles targetFolder, rowCounter
End Sub

Sub ListFiles(ByRef currentFolder As Object, ByRef rowCounter As Long)
    'フォルダ内のファイルを1つずつ取得
    Dim fileItem As Object
    For Each fileItem In currentFolder.Files
        'ファイルの拡張子が.xlsxの場合のみ処理
        If LCase(Right(fileItem.Name, 5)) = ".xlsx" Then
            'シート1のB列、rowCounter行目にファイル名を入力
            Sheets(1).Range("B" & rowCounter).Value = fileItem.Name
            
            '次の行へ
            rowCounter = rowCounter + 1
        End If
    Next
    
    'サブフォルダを1つずつ取得
    Dim subFolderItem As Object
    For Each subFolderItem In currentFolder.SubFolders
        '再帰的に関数を呼び出し
        ListFiles subFolderItem, rowCounter
    Next
End Sub